tests consistency

2 files changed, 175 insertions, 0 deletions

diff --git a/test/pleroma/integration/federation_test.exs b/test/pleroma/integration/federation_test.exs
new file mode 100644
index 000000000..10d71fb88
--- /dev/null
+++ b/test/pleroma/integration/federation_test.exs
@@ -0,0 +1,47 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.Integration.FederationTest do
+  use Pleroma.DataCase
+  @moduletag :federated
+  import Pleroma.Cluster
+
+  setup_all do
+    Pleroma.Cluster.spawn_default_cluster()
+    :ok
+  end
+
+  @federated1 :"federated1@127.0.0.1"
+  describe "federated cluster primitives" do
+    test "within/2 captures local bindings and executes block on remote node" do
+      captured_binding = :captured
+
+      result =
+        within @federated1 do
+          user = Pleroma.Factory.insert(:user)
+          {captured_binding, node(), user}
+        end
+
+      assert {:captured, @federated1, user} = result
+      refute Pleroma.User.get_by_id(user.id)
+      assert user.id == within(@federated1, do: Pleroma.User.get_by_id(user.id)).id
+    end
+
+    test "runs webserver on customized port" do
+      {nickname, url, url_404} =
+        within @federated1 do
+          import Pleroma.Web.Router.Helpers
+          user = Pleroma.Factory.insert(:user)
+          user_url = account_url(Pleroma.Web.Endpoint, :show, user)
+          url_404 = account_url(Pleroma.Web.Endpoint, :show, "not-exists")
+
+          {user.nickname, user_url, url_404}
+        end
+
+      assert {:ok, {{_, 200, _}, _headers, body}} = :httpc.request(~c"#{url}")
+      assert %{"acct" => ^nickname} = Jason.decode!(body)
+      assert {:ok, {{_, 404, _}, _headers, _body}} = :httpc.request(~c"#{url_404}")
+    end
+  end
+end
diff --git a/test/pleroma/integration/mastodon_websocket_test.exs b/test/pleroma/integration/mastodon_websocket_test.exs
new file mode 100644
index 000000000..0f2e6cc2b
--- /dev/null
+++ b/test/pleroma/integration/mastodon_websocket_test.exs
@@ -0,0 +1,128 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.Integration.MastodonWebsocketTest do
+  use Pleroma.DataCase
+
+  import ExUnit.CaptureLog
+  import Pleroma.Factory
+
+  alias Pleroma.Integration.WebsocketClient
+  alias Pleroma.Web.CommonAPI
+  alias Pleroma.Web.OAuth
+
+  @moduletag needs_streamer: true, capture_log: true
+
+  @path Pleroma.Web.Endpoint.url()
+        |> URI.parse()
+        |> Map.put(:scheme, "ws")
+        |> Map.put(:path, "/api/v1/streaming")
+        |> URI.to_string()
+
+  def start_socket(qs \\ nil, headers \\ []) do
+    path =
+      case qs do
+        nil -> @path
+        qs -> @path <> qs
+      end
+
+    WebsocketClient.start_link(self(), path, headers)
+  end
+
+  test "refuses invalid requests" do
+    capture_log(fn ->
+      assert {:error, {404, _}} = start_socket()
+      assert {:error, {404, _}} = start_socket("?stream=ncjdk")
+      Process.sleep(30)
+    end)
+  end
+
+  test "requires authentication and a valid token for protected streams" do
+    capture_log(fn ->
+      assert {:error, {401, _}} = start_socket("?stream=user&access_token=aaaaaaaaaaaa")
+      assert {:error, {401, _}} = start_socket("?stream=user")
+      Process.sleep(30)
+    end)
+  end
+
+  test "allows public streams without authentication" do
+    assert {:ok, _} = start_socket("?stream=public")
+    assert {:ok, _} = start_socket("?stream=public:local")
+    assert {:ok, _} = start_socket("?stream=hashtag&tag=lain")
+  end
+
+  test "receives well formatted events" do
+    user = insert(:user)
+    {:ok, _} = start_socket("?stream=public")
+    {:ok, activity} = CommonAPI.post(user, %{status: "nice echo chamber"})
+
+    assert_receive {:text, raw_json}, 1_000
+    assert {:ok, json} = Jason.decode(raw_json)
+
+    assert "update" == json["event"]
+    assert json["payload"]
+    assert {:ok, json} = Jason.decode(json["payload"])
+
+    view_json =
+      Pleroma.Web.MastodonAPI.StatusView.render("show.json", activity: activity, for: nil)
+      |> Jason.encode!()
+      |> Jason.decode!()
+
+    assert json == view_json
+  end
+
+  describe "with a valid user token" do
+    setup do
+      {:ok, app} =
+        Pleroma.Repo.insert(
+          OAuth.App.register_changeset(%OAuth.App{}, %{
+            client_name: "client",
+            scopes: ["read"],
+            redirect_uris: "url"
+          })
+        )
+
+      user = insert(:user)
+
+      {:ok, auth} = OAuth.Authorization.create_authorization(app, user)
+
+      {:ok, token} = OAuth.Token.exchange_token(app, auth)
+
+      %{user: user, token: token}
+    end
+
+    test "accepts valid tokens", state do
+      assert {:ok, _} = start_socket("?stream=user&access_token=#{state.token.token}")
+    end
+
+    test "accepts the 'user' stream", %{token: token} = _state do
+      assert {:ok, _} = start_socket("?stream=user&access_token=#{token.token}")
+
+      capture_log(fn ->
+        assert {:error, {401, _}} = start_socket("?stream=user")
+        Process.sleep(30)
+      end)
+    end
+
+    test "accepts the 'user:notification' stream", %{token: token} = _state do
+      assert {:ok, _} = start_socket("?stream=user:notification&access_token=#{token.token}")
+
+      capture_log(fn ->
+        assert {:error, {401, _}} = start_socket("?stream=user:notification")
+        Process.sleep(30)
+      end)
+    end
+
+    test "accepts valid token on Sec-WebSocket-Protocol header", %{token: token} do
+      assert {:ok, _} = start_socket("?stream=user", [{"Sec-WebSocket-Protocol", token.token}])
+
+      capture_log(fn ->
+        assert {:error, {401, _}} =
+                 start_socket("?stream=user", [{"Sec-WebSocket-Protocol", "I am a friend"}])
+
+        Process.sleep(30)
+      end)
+    end
+  end
+end